Quark XPress – Dokumente automatisch aufbauen lassen

Wer im Medienbereich zuhause ist, der wird sich mit Quark XPress gut auskennen. Egal welche Version, ob Quark 3.32, 4.0 oder jetzt 5.0. Eines hat Quark XPress schon immer gehabt: seine AppleScript-Fähigkeit. So gut wie jeder Schritt in Quark kann so per Fernsteuerung ausgeführt werden und so komplexe Satz-Aufgaben automatisiert werden.

Es können Rahmen an bestimmten Koordinaten angelegt werden, Texte hineingeladen und mit Stilvorlagen ausgezeichnet werden. Auch Bilder können automatisch plaziert werden und die Bilder sogar proportional vergrößert werden, so dass die gesamte Bildfläche zu sehen ist. Es wird das Bild dann automatishc richtig skaliert.

 

Skript: Neues Dokument anlegen:

tell application "QuarkXPress Passport™ 5"

activate

make new document

tell document 1

make new page at end

end tell

end tell

Es wird ein neues Dokument angelegt und darin eine neue leere Seite erzeugt. Hier kann man gut die Objektstruktur von Quark erkennen. Zuerst wird das Programm angesprochen. Es wird ein neues Dokument angelegt. Wenn wir jetzt versucht hätten, direkt eine neue Seite zu erzeugen, wäre eine Fehlermeldung gekommen. Denn es würde die Information fehlen, in welchem geöffneten Dokument eine neue Seite angelegt werden soll.

"Document 1" ist das derzeit aktive Dokumentfenster, welches im Vordergrund liegt. Man kann Dokument auch mit ihrem Dokumentnamen ansprechen, aber wir haben ja noch keinen Namen vergeben.

 

Skript: Neues Dokument anlegen, Text einsetzen und formatieren:

tell application "QuarkXPress Passport™ 5"

activate

make new document

tell document 1

make new page at end

tell page 1

make new text box with properties {bounds:{20, 80, 60, 150}} at beginning

tell text box 1

set story 1 to "Dieser Text wurde automatisch geladen"

set size of story 1 to 18

set font of story 1 to "Times"

set color of story 1 to "Blau"

set story 1 to story 1 & (ASCII character 13) & "Hier gehts weiter ..."

end tell

end tell

end tell

end tell

Hier wird zusätzlich noch eine Textbox aufgezogen und ein Text eingefügt. Dieser wird noch mit Schriftstilen wie Schriftart, Größe und Farbe versehen.

 

Skript: Bildrahmen anlegen:

tell document 1 of application "QuarkXPress Passport™ 5"

activate

tell page 1

make new picture box with properties {bounds:{20, 80, 60, 150}} at beginning

tell picture box 1

set image 1 to ("Mac23:Bilder:Bilder-CD 1 Fische:Dhifushi Outside Walhai ~.2002:anemone.JPG" as alias)

end tell

end tell

end tell

In diesem Skript wird auf die erste Seite eines offenen Quark-Dokuments ein neuer Bildrahmen positioniert und ein bestimmtes Bild von der Festplatte geladen.

Wichtig: Wenn es um Rahmenpositionen bzw. Koordinaten geht, so interpretiert Quark Zahlen immer so, wie dies in den Programmvoreinstellungen eingestellt ist. Wenn also beispielsweise im Quark Millimeter als Standard-Masseinheit gewählt ist, so werden die im Skript verwendeten Koordinaten ebenfalls als Millimeter interpretiert. Über diesen Sachverhalt kann man öfters mal stolpern, weil nur Rahmen im Arbeitsbereich angelegt werden können. Bei falschen Programmeinstellungen kommt man mit seinen Werten dann schnell außerhalb des Arbeitbereichs.

 

Skript: Alle Bilder proportional in die Rahmen einpassen:

tell document 1 of application "QuarkXPress Passport™ 5"

activate

set myCount to count pages

repeat with i from 1 to myCount

tell page i

set myPictBoxCount to count every picture box

repeat with i1 from 1 to myPictBoxCount

tell picture box i1

show

set bounds of image 1 to proportional fit

end tell

end repeat

end tell

end repeat

end tell

In diesem Skript wird ein komplettes Quark-Dokument Seite für Seite und Bildrahmen für Bildrahmen durchlaufen. Jedes Bild wird proportional in den Bildrahmen skaliert. Dies wird mit Hilfe von Schleifen realisiert.

Zuerst werden die Seiten gezählt, und dann die Anzahl Bildrahmen auf jeder Seite. Auf diese Weise wird jeder Bildrahmen im Dokument durchgearbeitet.

 

Skript: Einzelseiten-EPS erzeugen

tell document 1 of application "QuarkXPress Passport™ 5"

activate

set myDokName to name

repeat with i from 1 to count pages

save page i in myDokName & ".eps" & i EPS format Mac color EPS data binary EPS OPI include images

end repeat

end tell

Dieses Skript kann sehr hilfreich sein. Manchmal ist es notwendig, von einem bestehenden Quark-Dokument alle Seiten als Ganzseiten-EPS zu haben. Normalerweise müßte man dies so machen, dass man auf jede Seite geht, und hier die Funktion "Seite als EPS sichern..." anwählen. Wenn es viele Dokumente und Seiten sind, ist dies ein sehr monotoner Job.

Dies läßt sich per AppleScript komplett automatisieren. Einfach das Dokument aufmachen und das Script starten. Am Ende liegen im Quark Programm-Ordner die Einzelseiten-EPS mit Seitenzahl am Ende bereit.

 

Alle diese Skripte laufen sowohl mit Quark 3,4 und 5. Mit Quark 5 wurde der Funktionsumfang nochmals enorm erweitert. Besonders die Tabellenfunktion ist auch beim Scripten äußerst nützlich. Es ist klar, dass eine vollautomatische Quark-Seiten-Generierung nur über eine Datenbank-Anwendung laufen kann. Denn das AppleScript muß die Texte und Bilder irgendwo herbekommen, um sie in Quark umsetzen zu können.

Als Datenquelle der Texte werden wir uns im weiteren auf FileMaker Pro festlegen. Als Bildquelle gehen wir verstärkt auf Cumulus ein. Beide Werkzeuge werden im Rahmen des AppleScript-Forums noch näher behandelt werden.

 

 

email-kontakt

 

Autor: Christian Abele